3410 PRINT "ENTER SLOT OR PRESS RETURN FOR SLOT ";SL;: CALL -1008: POKE -16368,0: GET A$: PRINT A$;: IF A$ = CHR$(13) THEN GOTO 3430
3420 SL = VAL(A$): IF SL <1 OR SL >7 THEN SL = 6: GOTO 3400
3430 VTAB 12: HTAB 1: PRINT "ENTER DRIVE OR PRESS RETURN FOR DRIVE ";DR;: CALL -1008: POKE -16368,0: GET A$: PRINT A$;: IF A$ = CHR$(13) THEN 3450
3440 DR = VAL(A$): IF DR < >1 AND DR < >2 THEN 3430
3450 HOME : PRINT D$; LEFT$("CATALOG",7 -4 *PRODOS);",S";SL;",D";DR: IF PRODOS THEN PRINT CHR$(4)"PREFIX,S";SL;",D";DR
3460 GET A$
3470 POKE 216,0
3480 TEXT : GOTO 3090
3490 REM <<<<<LOAD DISK ERROR>>>>
3500 PRINT : PRINT
3510 PRINT : PRINT : PRINT "<<<<DISK ERROR>>>>"
3520 PRINT : PRINT "PRESS RETURN TO CONTINUE ";: POKE -16368,0: GET Z$
3530 POKE 216,0
3540 GOTO 3090
3550 REM <<< FILE NOT FOUND >>>
3560 PRINT : PRINT : PRINT "<<<<FILE NOT FOUND>>>>"
3570 PRINT : PRINT "PRESS RETURN TO CONTINUE ";: POKE -16368,0: GET Z$
3580 POKE 216,0
3590 GOTO 3090
3600 REM *********************
3610 REM * *
3620 REM * END *
3630 REM * *
3640 REM *********************
3650 TEXT : HOME
3660 VTAB 12:A$ = "ARE YOU SURE YOU WANT TO QUIT?": GOSUB 4090: POKE -16368,0: GET A$: IF A$ = "Y" OR A$ = "y" THEN HOME : VTAB 23: END
3670 GOTO 2110
3680 REM *** VIEW PUZZLE ***
3690 TEXT : HOME
3700 VTAB TP
3710 FOR Y = TP TO BT
3720 HTAB LF
3730 FOR X = LF TO RT
3740 IF ASC(AA$(X,Y)) >91 THEN PRINT CHR$( ASC(AA$(X,Y)) -32);: GOTO 3760
3750 PRINT AA$(X,Y);
3760 NEXT X
3770 PRINT
3780 NEXT Y
3790 GOTO 1030
3800 REM ********************
3810 REM * *
3820 REM * GET A WORD *
3830 REM * *
3840 REM ********************
3850 HTAB X: VTAB Y
3860 H = X:V = Y
3870 F = 0
3880 A$ = ""
3890 REM ---> C$=CURSOR
3900 C$ = CHR$(32)
3910 HTAB H: VTAB V: PRINT C$;
3920 HTAB H: VTAB V: GET AA$
3930 IF AA$ > CHR$(96) AND AA$ < CHR$(123) THEN AA$ = CHR$( ASC(AA$) -32)
3940 IF AA$ = CHR$(13) AND LEN(A$) >0 THEN 4080
3950 IF AA$ = CHR$(8) THEN H = H -1: GOTO 4030
3960 IF AA$ = CHR$(27) AND LEN(A$) >0 THEN HTAB X: VTAB Y: PRINT SPC( MAX +1);: GOTO 3850
3970 IF AA$ = CHR$(27) AND LEN(A$) = 0 THEN F = 1: GOTO 4080
3980 IF NOT PF AND (AA$ <"A" OR AA$ >"Z") THEN 3920
3990 HTAB H: VTAB V: PRINT AA$;
4000 A$ = A$ +AA$
4010 IF LEN(A$) = MAX +1 THEN A$ = LEFT$(A$,MAX): GOTO 3910
4020 H = H +1: GOTO 3910
4030 IF H <X THEN H = X: GOTO 3910
4040 IF LEN(A$) = 1 THEN A$ = "": GOTO 4060
4050 A$ = LEFT$(A$, LEN(A$) -1)
4060 HTAB H +1: VTAB V: PRINT " ";
4070 GOTO 3910
4080 HTAB H: VTAB V: PRINT " ";: RETURN
4090 HTAB 20 - LEN(A$)/2 +1: PRINT A$;: RETURN
4100 IF NOT PRODOS THEN NF = 1: RETURN
4110 NF = 1: IF LEN(F$) >0 THEN FOR NC = 1 TO LEN(F$):NA = ASC( MID$ (F$,NC,1)):NF = ((NA >64 AND NA <91) OR (NA = 46) OR (NA >47 AND NA <58 AND NC >1)) AND NF = 1: NEXT : IF LEN(F$) >15 OR LEFT$(F$,1) = "." THEN NF = 0